I wrote this program and posted it to the Willard list years ago when I  
used to do this sort of thing for a living. It might serve as a  
lighthouse in the fog of propeller confusion.  
  
For the computer semi-literate, here is a program, written in  
elementary BASIC, for calculating the proper propeller for displacement  
boats. It also performs a horsepower calculation necessary to achieve  
hull speeds and indicates the efficiency of various propeller pitches,  
diameters, and rpms. This program works better than the one used by  
Michigan Wheel or Federal Propeller. It will run on ANY computer which  
supports a Basic interpreter. Try it and see.  
  
I must caution that propeller specification is an arcane art full of  
compromises and approximations. It is rare good fortune if you get it  
right the first time. This program will get you in the ballpark, about  
+ or - 10% of the right value. From there on it is experimental trial  
and error. From a theoretical point of view pure displacement hulls  
work best with large, slow turning props. Generally the diameter is  
determined by hull clearances. The pitch is the main variable under  
your control. Fortunately the pitch of most bronze propellers can be  
adjusted a couple of inches either way at relatively low cost. While  
the program is designed to give you the most efficient prop for a given  
engine speed, reduction ratio and hull speed, most of us can live with,  
and even enjoy boats that donâ€™t squeeze the last mile from a tank of  
fuel.  
  
The logic of the program is simple. After entering hull and engine  
characteristics, hull speed is calculated using the standard formula KT  
= 1.34 x âˆšWL. An estimate of power required to reach hull speed is  
obtained using Keithâ€™s formula (line 90). This usually works out to  
about 1 HP per 500lbs displacement. A slip estimate is made using  
Gerrâ€™s formula for diplacement hulls (line 110). Given power, slip and  
shaft RPM, propeller pitch and diameter are calculated using Crouchâ€™s  
method. Don't be concerned if you don't know the names. All are naval  
architects who worried a lot about propellers.  
  
The more complex Bp method of propeller specification favored by the  
mathematically inclined is used as a check on the simpler approach. Va  
is estimated (lines 347, 348) and Bp is calculated (line 350). Lines  
350 through 410 provide estimates of Delta, P/D ratio and efficiency  
based on the Taylor Bp charts. The calculation is made to provide  
optimum efficiency at a given Bp. This approach is fully explained in  
Gerr's "Propeller Handbook."  
  
In both cases, engine power is derated 5% to account for gearbox and  
shaft losses. Small modifications in propeller specification (up to  
15%) are usually acceptable if pitch is increased 2â€ for every 1â€  
decrease in diameter.  
  
Of course you may not want the most efficient propeller for a sailboat  
or motorsailer. Efficient propellers tend to be big and have a lot of  
blade area. This translates into unacceptable drag when sailing. In  
that case, play around with the prop RPM and the diameter until you  
find one that suits.  
  
This is a bare bones program written in elementary Basic. It should run  
on any computer which supports a Basic interpreter, even palmtops. All  
PCs can run it from the TRS 80 or Commodore Pet to the iMac. Of course  
you have to get a free copy of ChipBasic for Macs from the web. I use  
it on an old HP200 LX palmtop running a copy of Radio Shack Basic for  
the PC. No provision is made for printing. I assume that you have a  
pencil and pad handy to record the results. There is minimal error  
checking. No provision is made for stupid entries. If you suggest that  
an 8 ton boat can be powered by a 1.5 hp outboard, you will get an  
absurd result. If you have a Basic interpreter, simply copy the text  
file starting at line 10. Most Basic programs are able to interpret  
text files.  
  
If you have comments or questions, contact me at: [LRZeitlin@...](http://groups.yahoo.com/group/WillardBoatOwners/post?postID=0aS6SdiSP1VhQFWKl6BHnbt2m4b2fSOK1OazKeZ2O5xW1cTgmrbcgAsIxQ3i1fgZthKGM6h3dUs5)  
  
BASIC PROPELLER CALCULATION FOR DISPLACEMENT HULLS  
  
10 PRINT "Propeller calculation program"  
20 PRINT "Copyright 1997: L. Zeitlin"  
27 FOR x = 1 TO 30000!: NEXT x  
29 PRINT: PRINT "CROUCH'S METHOD FOR OPTIMUM HULL SPEED PROPELLER  
CALCULATION."  
30 INPUT "Waterline length in ft."; L  
40 INPUT "Displacement in lbs.";D  
50 INPUT "Engine rated HP"; HP  
52 HP=HP\*.95 'assume 5% HP loss in power line.  
55 INPUT "Engine RPM at rated HP"; RPM  
57 INPUT "Percent RPM used for calculations";PRPM  
58 DRPM=PRPM\*RPM/100 'desired RPM  
59 HPREV=HP/RPM 'horsepower per revolution.  
60 INPUT "Gearbox reduction ratio"; RG  
70 HS= L^.5 \* 1.34 'hull speed calculation.  
80 PRINT "Hull speed ="; INT(HS \*100)/100;"KT"  
90 RHP = D \* ((HS/(11.963 \* L^.5))^3) ' Keith's formula, required HP  
for hull speed.  
100 PRINT "Required HP ="; INT(RHP \*100)/100  
105 IF RHP > HPREV\*DRPM THEN GOTO 900  
110 SLIP = 1.4/(HS^.57) 'estimate of slip, Gerr's formula  
120 HSRPM = DRPM/RG 'desired shaft RPM at hull speed.  
130 PITCH = (HS\*1215.6/(1-SLIP))/HSRPM  
140 DIAMETER = (632.7 \* ((HPREV\*DRPM)^.2))/HSRPM^.6  
150 PRINT:PRINT "Three bladed propeller:"  
160 PRINT "Diameter ="; INT(DIAMETER \* 10)/10; "inches."  
170 PRINT "Pitch =" INT(PITCH \* 10)/10; "inches."  
180 PRINT:PRINT "Two bladed propeller:"  
190 PRINT "Diameter ="; INT(DIAMETER \* 10.5)/10; "inches."  
200 PRINT "Pitch =" INT(PITCH \* 10.1)/10; "inches."  
205 PRINT "Slip estimate=";INT(SLIP\*100)/100;"percent.  
210 Thrust = 62.72 \*((HP\*PRPM/100\*DIAMETER/12)^.67)  
220 PRINT: PRINT "Static thrust =";INT(Thrust \* 10)/10;"pounds."  
225 PRINT:INPUT "Would you like to try another calculation using  
Crouch's method (Yes=1, No=2)";Q  
226 CLS  
227 IF Q=1 THEN GOTO 30  
230 PRINT:INPUT "Would you like to try the Bp method of optimum  
propeller calculation (Yes=1, No=2)"; Q  
240 IF Q=2 THEN GOTO 500  
250 CLS  
260 PRINT "Bp METHOD OF OPTIMUM PROPELLER CALCULATION."  
263 INPUT "Choose method: (1) Calculate block coefficient. (2) Use  
average block coefficient."; Q  
264 IF Q=2 THEN GOTO 300  
270 INPUT "Waterline beam in ft. =";WLB  
280 INPUT "Hull draft, excluding keel or skeg, in ft. ="; DFT  
290 Cb = D/(L\*WLB\*DFT\*64)  
295 PRINT "Block coefficient ="; INT(Cb \* 100)/100  
296 GOTO 303  
300 Cb = .53  
303 INPUT "Desired engine RPM"; DRPM: DHP = DRPM \* HPREV  
306 PRINT "Available shaft HP at desired RPM ="; INT(DHP \*10)/10  
310 INPUT "Desired speed in Kt."; HS  
313 RHP = D \* ((HS/(11.916 \* L^.5))^3) 'required HP for desired speed.  
316 IF RHP > HPREV\*DRPM THEN GOTO 1000  
318 PRINT "Required HP for desired speed ="; INT(RHP \*10)/10  
320 SRPM = DRPM /RG 'shaft RPM.  
330 SHP = DHP 'available HP at desired RPM  
335 DX=0  
347 Wf = 1.11 -(.6\*Cb)  
348 Va = HS \* Wf  
349 PRINT "Va="; INT(Va\*100)/100  
350 BP = (SRPM \* SHP^.5)/Va^2.5  
355 PRINT "BP"; INT(BP \*10)/10  
360 DELTA = 103.143 + (4.73 \* BP) -(.034 \* BP^2) + ((1.57/10000) \*  
BP^3) - ((2.964/10^7)\* BP^4)  
365 DIAFT = (Va\*DELTA)/SRPM  
367 PRATIO = 1.014 - (.014 \* BP) + ((1.72/10000) \* BP^2) -  
((9.873/10^7) \* BP^3) + ((2.047/10^9) \* BP^4)  
370 PRINT "DELTA"; INT(DELTA \*10)/10  
375 PRINT "DIAFT"; INT(DIAFT \*100)/100  
380 DIAIN = DIAFT \* 12  
395 PRINT"P/D RATIO"; INT(PRATIO \*100)/100  
397 PITCH = PRATIO\*DIAFT  
398 SLIP = 1-(HS\*101.3/(PITCH\*SRPM))  
410 EFF = .742 - (.006 \* BP) + ((5.086/10^5) \* BP^2) - ((2.209/10^7) \*  
BP^3) + ((3.835/10^10) \* BP^4)  
420 PRINT "Three blade prop diameter ="; INT(DIAIN \*100)/100;"inches."  
425 PRINT "Two blade prop diameter =" INT(DIAIN \* 105)/100;"inches."  
430 PRINT "Pitch ="; INT(PRATIO \* DIAIN\*100)/100;"inches."  
440 PRINT "Slip ="; INT(SLIP\*100)/100;"percent."  
450 PRINT "Efficiency ="; INT((EFF-(DX/2))\*100)/100; "percent."  
451 Thrust = 62.72 \*((RHP\*DIAFT)^.67)  
452 PRINT "Static thrust =";INT(Thrust \* 10)/10;"pounds."  
455 PRINT: INPUT "Do you wish to modify engine and speed variables  
(Yes=1, No=2)";Q  
456 IF Q=1 THEN GOTO 303  
457 INPUT "Do you wish to change recommended propeller diameter (Yes=1,  
No=2)";Q  
458 IF Q=1 THEN GOSUB 2000  
460 PRINT:INPUT "Another propeller calculation? (Yes=1, No=2)"; Q  
465 IF Q=1 THEN CLS: GOTO 29  
470 'IF Q=1 THEN GOTO 30  
500 PRINT "GOODBYE"  
505 FOR x = 1 TO 10000: NEXT x  
510 END  
  
900 PRINT "The engine does not have enough power to reach indicated  
speed."  
902 INPUT "Do you wish to modify initial variables (Yes=1, N=2)";Q  
903 IF Q=1 THEN GOTO 30  
904 IF Q=2 THEN GOTO 500  
905 RETURN  
  
1000 PRINT "The engine does not have enough power to reach indicated  
speed."  
1002 INPUT "Do you wish to modify initial variables (Yes=1, N=2)";Q  
1003 IF Q=1 THEN GOTO 303  
1004 IF Q=2 THEN GOTO 500  
1005 RETURN  
  
2000 INPUT "Desired diameter in inches"; DDIAIN  
2005 DX = 1-(DDIAIN/DIAIN)  
2010 DIAFT =DDIAIN/12  
2020 DELTA = (SRPM \* DIAFT)/Va  
2025 PRATIO = (3.28)  
-(.03\*DELTA)+((1.231/10000)\*DELTA^2)-((1.719/10000000#)\*DELTA^3)  
2027  
2030 GOTO 370  
2040 RETURN  
  
  
  
  
Larry Zeitlin  
Lakeview Research, Inc  
Cortlandt Manor, NY

PROPELLER SPECIFICATION

Let's start with the basics of the propeller mystique.

Compared to most of the power transmission device we are familiar with, a propeller is comparatively inefficient, often losing more than half of the available engine power to slip, turbulence, blade drag,

friction, etc. Although a well designed boat propulsion system can be as much as 60% efficient, most are in the 40 to 50% range. A bicycle, on the other hand, converts as much as 95% of the applied power to

forward motion.

The recipe for maximizing thrust and increasing efficiency is to use a large, slow turning propeller, as clear as possible from such boat structures as rudders or deadwood. See your neighborhood tugboat for a good example. Unfortunately, this approach also maximizes drag when the propeller is not turning. Sailboat designers have to compromise, accepting lower efficiency for lower drag. Ideally a sailboat would

have a retractable prop or a lifting outboard for use when sailing.Folding or feathering props are the next best. In most other cases, the designers of performance sailboats with fixed props have opted for the

smallest, fastest turning prop that can adequately move the boat, efficiency be damned. Motorsailers with large diameter props finesse the problem by keeping the engine ticking over when sailing, contributing little to the propulsion, but effectively negating prop drag. I know some cruising sailboat owners that carry two props, a small two blade prop for use when the trip involves long sailing passages, and a larger three blade prop for use when they anticipate a long trip mostly under power. I assume they keep the shaft well greased so they can change props easily using scuba gear.

The maximum practical speed that a displacement hull can reach in knots is the "hull" speed. This is generally defined as 1.34 times the square root of the waterline length in feet. It takes very little power to move a displacement boat at slow speeds but the required power increases as the cube of the speed increase until the hull speed is reached. At that point the power requirements increase even more sharply and few displacement boats can carry enough power to exceed hull speed by more than a few knots. Allowing for average driveline losses and propeller efficiency, it takes an engine providing about 1

hp per 500 lbs. of displacement to move the boat at hull speed. This is a conservative estimate but implies that a 16,000 lb displacement type boat should be equipped with an engine capable of 32 hp continuous output. If the boat is intended for cruising and will be operated long hours under power then the engine should drive a larger prop through a reduction gear.

As far as props themselves go, for displacement boats, it is the blade area that counts. It makes little difference in power transmission if it is a two or three blade prop. For sailboats, a two blader is

preferred since it can be locked in a vertical postion behind the deadwood, minimizing drag under sail. A three blader will have less vibration and can be slightly smaller in diameter (say 5%) for the same

performance under power. The pitch and diameter of the prop are interrelated for optimum efficiency. By and large, the diameter should be as large as practical, allowing for a minimum three inch clearance

between the prop and all hull structures. The pitch should be selected so that the engine, if a diesel, is turning about 80 to 85% of maximum continuous RPM at hull speed. This assumes adequate engine power at that RPM to reach that speed. Gasoline engines should be propped so that hull speed is reached at 90 to 95% of max. continuous RPM. In general a decrease in pitch of 1 inch increases engine speed by 200 RPM. Most bronze props can be changed in pitch by 2 inches either way by a prop rebuilder.

The proper specification of a propeller for a displacement boat depends on the waterline length, the cruising displacement, the block coefficient, the available power, the reduction ratio, the maximum

continuous engine RPM, the percent power to be utilized, and for all I know, the phase of the moon. Dave Gerr's "Propeller Handbook" gives a variety of methods for calculation but requires some degree of

mathematical sophistication and complicated boat measurements for the best results. Skene's "Elements of Design" gives a simpler and perhaps less precise technique but adequate for most uses.

The most efficient prop isn't always the best one for a given boat. Take my personal experience as a case in point. I had a older Willard Horizon motorsailer, essentially the same boat as the Willard 30 trawler except with a mast and sail. It was powered by a venerable Perkins 4-107 driving a 2.57 reduction gear. Prop calculation programs show that for maximum efficiency at hull speed using 80% continuous

engine RPM, I should be running a 22" diameter, 13" pitch prop. The efficiency of this prop would be slightly above 50%. Slip would be 30%.But since I enjoy sailing with the engine off, fitting a maximum

efficiency prop would be equivalent to dragging an anchor. The water resistance of a fixed 22" prop would knock 2 or 3 knots off the already marginal sailing performance of the Willard.

To combat the drag, most motorsailers keep the engine ticking over at a fast idle, about 1000 RPM, when sailing. This eliminates prop drag and lets the boat make reasonable progress to windward. Because the prop is very lightly loaded and is turning at a slow shaft speed, you want a relatively high pitch, say 16" to 18". But then when slogging against a headwind or current when motoring, a pitch that high would overload the engine with a 22" diameter prop. The answer is to reduce the diameter a few inches. After some trial and error we finally settled on a 18" diameter, 16" pitch prop as a reasonable compromise.

My boat was happiest when the engine turned at about 2000 RPM. Sound treatment on the early Willards is notable by its absence and you are always aware of engine noise and vibration under power. Around 2000 RPM there is a minimum of panel resonance and sympathetic vibration. With a prop pitch of 16" the boat could move at near hull speed at 2000 RPM but the engine could not get up to its continuous rated speed of 3000 RPM. Further the speed at idle was about 3 kts. Maneuvering in a crowded marina required repeated shifts into neutral to slow the boat down. The conclusion had to be that a 16" pitch was too high.

Finally we reduced the pitch to 14", almost that specified by the prop program. Speed at idle dropped to a bit over 2 kts and the engine could now rev up to the point where it delivers most of its rated power. Hull

speed is reached at about 2400 RPM, still within the comfort range. The compromises cost me a bit of efficiency and increased slip. The efficiency was now 41% and the slip was 35%. Over a season I used about 20 gallons more fuel than with the maximum efficiency prop but the boat was far more pleasant to motor and sail.

Larry Z

MSG #14100 of 12/15/2011